next | previous | forward | backward | up | top | index | toc | Macaulay2 web site
NormalToricVarieties :: isAmple

isAmple -- whether a torus-invariant Weil divisor is ample

Synopsis

Description

A Cartier divisor is very ample when it is basepoint free and the map arising from its complete linear series is a closed embedding. A Cartier divisor is ample when some positive integer multiple is very ample. For a torus-invariant Cartier divisor D on a complete normal toric variety, the following conditions are equivalent:
  • D is ample;
  • the real piecewise linear support function associated to D is strictly convex;
  • the lattice polytope corresponding to D is full-dimensional and its normal fan equals the fan associated to the underlying toric variety;
  • the intersection product of D with every torus-invariant irreducible curve is positive.

On projective space, every torus-invariant prime divisor is ample.

i1 : PP3 = projectiveSpace 3;
i2 : all(#rays PP3, i -> isAmple PP3_i)

o2 = true
On a Hirzebruch surface, none of the torus-invariant prime divisors are ample.
i3 : X1 = hirzebruchSurface 2;
i4 : any(#rays X1, i -> isAmple X1_i)

o4 = false
i5 : D = X1_2 + X1_3

o5 = D  + D
      2    3

o5 : ToricDivisor on X1
i6 : isAmple D  

o6 = true
i7 : isProjective X1     

o7 = true
A normal toric variety is Fano if and only if its anticanonical divisors, namely minus the sum of its torus-invariant prime divisors, is ample.
i8 : X2 = smoothFanoToricVariety(3,5);
i9 : K = toricDivisor X2

o9 = - D  - D  - D  - D  - D  - D
        0    1    2    3    4    5

o9 : ToricDivisor on X2
i10 : isAmple (- K)

o10 = true
i11 : X3 = kleinschmidt(9,{1,2,3});
i12 : K = toricDivisor X3

o12 = - D  - D  - D  - D  - D  - D  - D  - D  - D  - D  - D
         0    1    2    3    4    5    6    7    8    9    10

o12 : ToricDivisor on X3
i13 : isAmple (-K)  

o13 = true

See also

Ways to use isAmple :