Currently,
R and
S must both be polynomial rings over the same base field.
This function first checks to see whether M will be a finitely generated R-module via F. If not, an error message describing the codimension of M/(vars of S)M is given (this is equal to the dimension of R if and only if M is a finitely generated R-module.
Assuming that it is, the push forward
F_*(M) is computed. This is done by first finding a presentation for
M in terms of a set of elements that generates
M as an
S-module, and then applying the routine
coimage to a map whose target is
M and whose source is a free module over
R.
Example: The Auslander-Buchsbaum formula
Let's illustrate the Auslander-Buchsbaum formula. First construct some rings and make a module of projective dimension 2.
i1 : R4 = ZZ/32003[a..d];
|
i2 : R5 = ZZ/32003[a..e];
|
i3 : R6 = ZZ/32003[a..f];
|
i4 : M = coker genericMatrix(R6,a,2,3)
o4 = cokernel | a c e |
| b d f |
2
o4 : R6-module, quotient of R6
|
i5 : pdim M
o5 = 2
|
Create ring maps.
i6 : G = map(R6,R5,{a+b+c+d+e+f,b,c,d,e})
o6 = map(R6,R5,{a + b + c + d + e + f, b, c, d, e})
o6 : RingMap R6 <--- R5
|
i7 : F = map(R5,R4,random(R5^1, R5^{4:-1}))
o7 = map(R5,R4,{- 3665a - 3884b - 2983c - 13577d + 15241e, - 14560a + 11330b + 12741c + 11767d + 10009e, 15075a + 11823b - 2943c + 7058d + 1904e, - 1518a + 9128b - 10956c - 12506d - 4396e})
o7 : RingMap R5 <--- R4
|
The module M, when thought of as an R5 or R4 module, has the same depth, but since depth M + pdim M = dim ring, the projective dimension will drop to 1, respectively 0, for these two rings.
i8 : P = pushForward(G,M)
o8 = cokernel | c -de |
| d bc-ad+bd+cd+d2+de |
2
o8 : R5-module, quotient of R5
|
i9 : pdim P
o9 = 1
|
i10 : Q = pushForward(F,P)
3
o10 = R4
o10 : R4-module, free, degrees {0..1, 0}
|
i11 : pdim Q
o11 = 0
|
Example: generic projection of a homogeneous coordinate ring
We compute the pushforward N of the homogeneous coordinate ring M of the twisted cubic curve in P^3.
i12 : P3 = QQ[a..d];
|
i13 : M = comodule monomialCurveIdeal(P3,{1,2,3})
o13 = cokernel | c2-bd bc-ad b2-ac |
1
o13 : P3-module, quotient of P3
|
The result is a module with the same codimension, degree and genus as the twisted cubic, but the support is a cubic in the plane, necessarily having one node.
i14 : P2 = QQ[a,b,c];
|
i15 : F = map(P3,P2,random(P3^1, P3^{-1,-1,-1}))
7 8 1 1 6 1 10 10 8
o15 = map(P3,P2,{-a + -b + -c + --d, 5a + b + -c + -d, 10a + --b + --c + -d})
2 9 3 10 7 6 3 7 7
o15 : RingMap P3 <--- P2
|
i16 : N = pushForward(F,M)
o16 = cokernel {0} | 23250807720ab-9352257600b2-11559465540ac+1187000598bc+1721485689c2 99646318800a2-47275670400b2-75642436800ac+49729842750bc+1222175052c2 39880721843435472249600b3-59821007407426743741900b2c+14807132217612000ac2+29910459855211715549700bc2-4985073488674882034775c3 0 |
{1} | 5396337060a-1767698464b-1335451691c 48551536440a-39365580800b-351124361c 29605721223537795387600a2-59941816205799354030000ab+46492092940165133184000b2+5508218911598776119120ac-21633503022718378804950bc+4247138241849262333336c2 1022463864000a3-2481421320000a2b+2118670848000ab2-541133107200b3+37962464400a2c-194785458000abc+35500617600b2c+37976955660ac2-738091900bc2-1954132789c3 |
2
o16 : P2-module, quotient of P2
|
i17 : hilbertPolynomial M
o17 = - 2*P + 3*P
0 1
o17 : ProjectiveHilbertPolynomial
|
i18 : hilbertPolynomial N
o18 = - 2*P + 3*P
0 1
o18 : ProjectiveHilbertPolynomial
|
i19 : ann N
3 2 2
o19 = ideal(1022463864000a - 2481421320000a b + 2118670848000a*b -
-----------------------------------------------------------------------
3 2 2
541133107200b + 37962464400a c - 194785458000a*b*c + 35500617600b c +
-----------------------------------------------------------------------
2 2 3
37976955660a*c - 738091900b*c - 1954132789c )
o19 : Ideal of P2
|
Note: these examples are from the original Macaulay script by David Eisenbud.