next | previous | forward | backward | up | top | index | toc | Macaulay2 web site
MultiplierIdeals :: logCanonicalThreshold

logCanonicalThreshold -- log canonical threshold

Description

The log canonical threshold of an ideal I is the infimum of t for which the multiplier ideal J(It) is a proper ideal. Equivalently it is the least nonzero jumping number.

log canonical threshold of a monomial ideal

Computes the log canonical threshold of a monomial ideal I.
R = QQ[x,y];
I = monomialIdeal(y^2,x^3);
logCanonicalThreshold(I)
S = QQ[x,y,z];
J = monomialIdeal(x*y^4*z^6, x^5*y, y^7*z, x^8*z^8); -- Example 7 of [Howald 2000]
logCanonicalThreshold(J)

thresholds of multiplier ideals of monomial ideals

  • Usage:
    logCanonicalThreshold(I,m)
  • Inputs:
  • Outputs:
    • a rational number, the least t such that m is not in the t-th multiplier ideal of I
    • a matrix, the equations of the facets of the Newton polyhedron of I which impose the threshold on m
Computes the threshold of inclusion of the monomial m=xv in the multiplier ideal J(It), that is, the value t = sup{c | m lies in J(Ic) }= min{c | m does not lie in J(Ic)}. In other words, (1/t)(v+(1,..,1)) lies on the boundary of the Newton polyhedron Newt(I). In addition, returns the linear inequalities for those facets of Newt(I) which contain (1/t)(v+(1,..,1)). These are in the format of Normaliz, i.e., a matrix (A | b) where the number of columns of A is the number of variables in the ring, b is a column vector, and the inequality on the column vector v is given by Av+b ≥0, entrywise. As a special case, the log canonical threshold is the threshold of the monomial 1R = x0.
R = QQ[x,y];
I = monomialIdeal(x^13,x^6*y^4,y^9);
logCanonicalThreshold(I,x^2*y)
J = monomialIdeal(x^6,x^3*y^2,x*y^5); -- Example 6.7 of [Howald 2001] (thesis)
logCanonicalThreshold(J,1_R)
logCanonicalThreshold(J,x^2)

log canonical threshold of a hyperplane arrangement

Computes the log canonical threshold of a hyperplane arrangement A.
R = QQ[x,y,z];
f = toList factor((x^2 - y^2)*(x^2 - z^2)*(y^2 - z^2)*z) / first;
A = arrangement f;
logCanonicalThreshold(A)

log canonical threshold of monomial space curves

  • Usage:
    logCanonicalThreshold(R,n)
  • Inputs:
    • R, a ring
    • n, a list, a list of three integers
  • Outputs:

Computes the log canonical threshold of the ideal I of a space curve parametrized by u →(ua,ub,uc).

R = QQ[x,y,z];
n = {2,3,4};
logCanonicalThreshold(R,n)

log canonical threshold of a generic determinantal ideal

  • Usage:
    multiplierIdeal(L,r)
  • Inputs:
    • L, a list, dimensions {m,n} of a matrix
    • r, an integer, the size of minors generating the determinantal ideal
  • Outputs:
Computes the log canonical threshold of the ideal of r ×r minors in a m ×n matrix whose entries are independent variables (a generic matrix).

lct of ideal of 2-by-2 minors of 4-by-5 matrix:

x = getSymbol "x";
R = QQ[x_1..x_20];
X = genericMatrix(R,4,5);
logCanonicalThreshold(X,2)
We produce some tables of lcts:
lctTable = (M,N,r) -> ( x = getSymbol "x"; R := QQ[x_1..x_(M*N)]; netList ( prepend( join({"m\\n"}, toList(3..M)), for n from 3 to N list ( prepend(n, for m from 3 to min(n,M) list ( logCanonicalThreshold(genericMatrix(R,m,n),r) )) )) ));
Table of LCTs of ideals of 3-by-3 minors of various size matrices (Table A.1 of [Johnson, 2003] (dissertation))
lctTable(6,10,3)
Table of LCTs of ideals of 4-by-4 minors of various size matrices (Table A.2 of [Johnson, 2003] (dissertation))
lctTable(8,14,4)

See also

Ways to use logCanonicalThreshold :